Adding Folders

*** Settings ***

Resource  plone/app/robotframework/server.robot
Resource  plone/app/robotframework/keywords.robot
Resource  Selenium2Screenshots/keywords.robot

Library  OperatingSystem

Suite Setup  Run keywords  Suite Setup  Test Setup
Suite Teardown  Run keywords  Test teardown  Suite Teardown

*** Variables ***

${FIXTURE}  plone.app.robotframework.PLONE_ROBOT_TESTING
@{DIMENSIONS}  1024  768
@{APPLY_PROFILES}  plone.app.contenttypes:plone-content


*** Keywords ***

Suite Setup
    Run keyword if  not sys.argv[0].startswith('bin/robot')
    ...             Setup Plone site  ${FIXTURE}
    Run keyword if  sys.argv[0].startswith('bin/robot')
    ...             Open test browser
    Run keyword and ignore error  Set window size  @{DIMENSIONS}

Test Setup
    Import library  Remote  ${PLONE_URL}/RobotRemote

    Run keyword if  sys.argv[0].startswith('bin/robot')
    ...             Remote ZODB SetUp  ${FIXTURE}

    ${language} =  Get environment variable  LANGUAGE  'en'
    Set default language  ${language}

    Enable autologin as  Manager
    ${user_id} =  Translate  user_id
    ...  default=jane-doe
    ${user_fullname} =  Translate  user_fullname
    ...  default=Jane Doe
    Create user  ${user_id}  Member  fullname=${user_fullname}
    Set autologin username  ${user_id}

Test Teardown
    Run keyword if  sys.argv[0].startswith('bin/robot')
    ...             Remote ZODB TearDown  ${FIXTURE}

Suite Teardown
    Run keyword if  not sys.argv[0].startswith('bin/robot')
    ...             Teardown Plone Site
    Run keyword if  sys.argv[0].startswith('bin/robot')
    ...             Close all browsers

Adding folders to a Plone web site is the basic way of controlling the organization of content.

You have undoubtedly created folders (directories) on your computer’s hard drive. Personal computers use a hierarchy of folders to structure and organize the programs and files on the hard drive. In Plone folders are essentially used the same way, except that they are created on a Plone web site, for organizing content in Plone’s built-in storage system.

Folders are added by clicking the Add new... drop-down menu. Select Folder from the menu:

*** Test Cases ***

Show add new folder menu
    Go to  ${PLONE_URL}

    Wait until element is visible
    ...  css=span.icon-plone-contentmenu-factories
    Click element  css=span.icon-plone-contentmenu-factories

    Wait until element is visible
    ...  css=#plone-contentmenu-factories li.plone-toolbar-submenu-header

    Mouse over  folder
    Update element style  portal-footer  display  none

    Capture and crop page screenshot
    ...  ${CURDIR}/../../_robot/adding-folders_add-menu.png
    ...  css=div.plone-toolbar-container
    ...  css=#plone-contentmenu-factories ul

You should now see the Add Folder screen:

*** Test Cases ***

Show new folder add form
    Page should contain element  folder
    Click link  folder

    Wait until element is visible
    ...  css=#form-widgets-IDublinCore-title

    Capture and crop page screenshot
    ...  ${CURDIR}/../../_robot/adding-folders_add-form.png
    ...  css=#content

Fill in the Title, which is required, as indicated by the red dot. The Summary is optional; you can always come back to the edit panel if you need to add a description of the folder. Summaries are useful when a site visitor uses the search tool included with Plone - results will display with both the Title and Summary of the item.

You also notice tabs along the top:

• Default, for entering the Title and Description fields,
• Categorization, for specifying categories that apply to the folder (you may know these as keywords),
• Dates, for setting the time period when the folder should be available for view on the web site,
• Ownership, for specifying the creator and/or contributors for the content item,
• Settings, for allowing comments about the item, enabling Next/Previous Navigation, and choosing whether it shows in the navigation menu for the web site.

These tabs are standard, so you’ll see them when you click other content types. We will cover these tabs in another section of this user manual.

Be sure to click Save at the bottom of the page when you are finished. This will complete the folder creation process.